REBOOK

Category: Dimensionality & hierarchies

Overview

Description	The REBOOK function can be used in all situations where value measures need to be "booked" to a different value in the same level. The FilterOperation allows further specifications on which level values should be rebooked. Use when you need to reclassify values from one level value to another within the same level.
Syntax	`REBOOK('Node', "Level", "OldValue", "NewValue" [, "FilterOperation"])`
Parameters	Node: Input node Level: The level in the input node that shall be re-booked. OldValue: The existing value whose value measure shall be rebooked (moved). This can either be a single value or a list of values. NewValue: The target value of the rebook. This should be a single string value. FilterOperation: The indicator for the filter operation is the `"OldValue"` entered in the formula. `"EQ"` (equality) - default `"NEQ"` (not equals) `"GT"` (greater than) `"GTE"` (greater than or equals) `"LT"` (less than) `"LTE"` (less than or equals)
Limitations	OldValue and NewValue must be level values of the same level inserted in the formula. If the node contains linked levels, it is not possible to rebook values of the linked-to dimension. Rebooking these values should be done via the initial dimension that the other dimension is linked to. Then all values are valid. Important: This function always keeps linked levels between dimensions. Do not use this function if you want the node to have different linked levels than the initial dimension.

Explanations of FilterOperations:

Operator	Description
`EQ`	The measures of the level value equal to the `"OldValue"` are rebooked to the `"NewValue"` (default).
`NEQ`	All measures of the level values not equal to the `"OldValue"` are rebooked to the `"NewValue"`.
`GT`	All measures of the level values greater than the `"OldValue"` are rebooked to the `"NewValue"`.
`GTE`	All measures of the level values greater than or equal to the `"OldValue"` are rebooked to the `"NewValue"`.
`LT`	All measures of the level values less than the `"OldValue"` are rebooked to the `"NewValue"`.
`LTE`	All measures of the level values less than or equal to the `"OldValue"` are rebooked to the `"NewValue"`.

The "OldValue" is the leading indicator. As the dimension list is sorted in a lexicographic order, "greater" targets all levels that start with a letter that alphabetically comes after the first letter of the "OldValue".

Examples

These examples show how values are moved from one segment to another within the same level, including list-based rebooking and filtered rebooking.

Input node: 'Revenue'

Year	Segment	Value
2025	MINI	100
2025	COMPACT	50
2025	LARGE	10

Example 1

This example moves the value of one segment into another existing segment.

Formula: REBOOK('Revenue', "Segment", "MINI", "LARGE")

Year	Segment	→ REBOOK Result
2025	MINI	0
2025	COMPACT	50
2025	LARGE	110

With this formula, the value measure of 'MINI' is rebooked to 'LARGE'. As LARGE already had a revenue of '10', the rebooked value of '100' is added (=110).

Calculation:

Year	Segment	→ REBOOK Result
2025	MINI	100 (-100)
2025	COMPACT	50
2025	LARGE	10 (+100)

Example 2

This example rebooks a list of source values into one target value.

Formula: REBOOK('Revenue', "Segment", ["MINI", "COMPACT"], "LARGE")

Year	Segment	→ REBOOK Result
2025	MINI	0
2025	COMPACT	0
2025	LARGE	160

With this formula, the value measures of 'MINI' and 'COMPACT' are rebooked to 'LARGE'. The 'OldValue' measures are combined and add up to the measure of 'LARGE'.

Calculation:

Year	Segment	→ REBOOK Result
2025	MINI	100 (-100)
2025	COMPACT	50 (-50)
2025	LARGE	10 (+100+50)

Example 3

This example uses the filter operation to rebook all values that do not match the source value.

Formula: REBOOK('Revenue', "Segment", "MINI", "LARGE", "NEQ")

Year	Segment	→ REBOOK Result
2025	MINI	100
2025	COMPACT	0
2025	LARGE	60

As the FilterOperation is set to "NEQ", all measures of the levels not equal to the "OldValue" (MINI) are rebooked to the "NewValue" (LARGE).

Calculation:

Year	Segment	→ REBOOK Result
2025	MINI	100
2025	COMPACT	50 (-50)
2025	LARGE	10 (+50)

Related Functions

Function	When to use instead
DISTRIBUTE	When values should be split across multiple level values using weights instead of moved from one level value to another.
REDISTRIBUTE	When values should be redistributed only within defined clusters rather than rebooked directly between level values.